10 exemples VLOOKUP pour les débutants et les utilisateurs avancés

La fonction VLOOKUP est la référence.

Si vous savez utiliser la fonction VLOOKUP, vous connaissez quelque chose sur Excel.

Si vous ne le faites pas, vous feriez mieux de ne pas mentionner Excel comme l'un de vos points forts sur votre CV.

J'ai fait un entretien de groupe et une fois qu'un candidat a mentionné Excel comme son domaine d'expertise, la première chose qui m'a été demandée était - vous avez compris - la fonctionnalité VLOOKUP.

Maintenant que nous connaissons l'importance de cette fonction Excel, il est logique de la saisir pleinement afin que nous puissions dire fièrement - "Je connais une chose ou deux dans Excel".

Cela va être un énorme tutoriel VLOOKUP (selon mes normes).

Je vais couvrir tout cela et ensuite vous montrer un exemple utile et pratique de VLOOKUP.

Quand utiliser la fonction VLOOKUP dans Excel ?

La fonction VLOOKUP fonctionne mieux lorsque vous recherchez des points de données correspondants dans une colonne, et lorsqu'un point de données correspondant est trouvé, vous prenez la colonne à droite de la ligne et obtenez la valeur à partir du nombre de cellules spécifié.

Prenons un exemple simple ici pour comprendre quand utiliser Vlookup dans Excel.

N'oubliez pas que tout le monde cherchait frénétiquement son nom et ses notes lorsque les résultats des tests sortaient et restaient collés sur les babillards (du moins c'est ce qui arrivait souvent quand j'étais à l'école).

Voici comment ça fonctionne:

• Vous allez au tableau d'affichage et commencez à chercher votre nom ou votre numéro d'enregistrement (déplacez votre doigt de haut en bas dans la liste).
• Une fois que vous avez trouvé votre nom, vous déplacerez vos yeux vers la droite du nom/numéro d'enregistrement pour voir votre score.

C'est exactement ce que fait la fonction RECHERCHEV d'Excel (n'hésitez pas à utiliser cet exemple lors de votre prochain entretien).

La fonction VLOOKUP recherche une valeur spécifiée dans une colonne (dans l'exemple ci-dessus, c'est votre nom), et lorsqu'elle trouve une correspondance spécifiée, elle renvoie une valeur (le jeton que vous obtenez) dans la même ligne.

syntaxe

=RECHERCHEV(lookup_value, table_array, col_index_num, [range_lookup])

Paramètres d'entrée

• valeur_de recherche –Il s'agit de la valeur de recherche que vous essayez de trouver dans la colonne la plus à gauche du tableau.Il peut s'agir d'une valeur, d'une référence de cellule ou d'une chaîne de texte.Dans l'exemple de la feuille de pointage, ce serait votre nom.
• table_array –Il s'agit du tableau de tables dans lequel vous recherchez des valeurs.Il peut s'agir d'une référence à une plage de cellules ou à une plage nommée.Dans l'exemple du tableau des scores, il s'agirait du tableau entier contenant les scores de chacun pour chaque matière
• col_index –Il s'agit du numéro d'index de colonne à partir duquel vous souhaitez obtenir des valeurs correspondantes.Dans l'exemple de table de fractions, si vous voulez la fraction mathématique (qui est la première colonne de la table qui contient la fraction), vous pouvez regarder la colonne 1.Si vous voulez un score physique, vous pouvez regarder les colonnes 1 et 2.
• [range_lookup] -Ici, vous pouvez spécifier si vous voulez une correspondance exacte ou une correspondance approximative.Si omis, la valeur par défaut est TRUE - correspondance approximative(voir notes complémentaires ci-dessous).

Notes supplémentaires (ennuyeuses, mais importantes à connaître)

• Les correspondances peuvent être exactes (FALSE ou 0 dans range_lookup) ou approximatives (TRUE ou 1).
• Dans une recherche approximative, assurez-vous que la liste est triée par ordre croissant (de haut en bas), sinon les résultats pourraient être inexacts.
• Lorsque range_lookup est TRUE (recherche approximative) et que les données sont triées par ordre croissant :
  • Si la fonction VLOOKUP ne trouve pas la valeur, elle renvoie la plus grande valeur inférieure à lookup_value.
  • Renvoie une erreur #N/A si lookup_value est inférieur à la valeur minimale.
  • Si lookup_value est du texte, des caractères génériques peuvent être utilisés (voir l'exemple ci-dessous).

Maintenant, j'espère que vous avez une compréhension de base de ce que la fonction VLOOKUP peut faire, épluchons l'oignon et voyons quelques exemples pratiques de la fonction VLOOKUP.

10 exemples Excel VLOOKUP (basique et avancé)

Voici 10 exemples utiles d'utilisation d'Excel Vlookup pour vous montrer comment l'utiliser dans votre travail quotidien.

Exemple 1 - Trouver le score mathématique de Brad

Dans l'exemple VLOOKUP ci-dessous, j'ai une liste avec les noms des étudiants dans la colonne la plus à gauche et les notes pour différentes matières dans les colonnes B à E.

Maintenant, mettons-nous au travail et utilisons la fonction VLOOKUP pour faire ce qu'elle fait le mieux.À partir des données ci-dessus, j'ai besoin de savoir ce que Brad a obtenu en mathématiques.

À partir des données ci-dessus, j'ai besoin de savoir ce que Brad a obtenu en mathématiques.

Voici la formule VLOOKUP qui renvoie le score mathématique de Brad :

=RECHERCHEV("Brad",$A$3:$E$10,2,0)

La formule ci-dessus a quatre paramètres :

• "Brad": - Il s'agit de la valeur de recherche.
• 3 $A$ : 10$E$ - C'est la gamme de cellules que nous examinons.N'oubliez pas qu'Excel recherche les valeurs de recherche dans la colonne la plus à gauche.Dans cet exemple, il recherche le nom Brad dans A3:A10, qui est la colonne la plus à gauche du tableau spécifié.
• 2 – Une fois que la fonction a trouvé le nom de Brad, elle passe à la deuxième colonne du tableau et renvoie la valeur dans la même ligne que Brad.Une valeur de 2 signifie ici que nous recherchons les scores de la deuxième colonne du tableau spécifié.
• 0 – Cela indique à la fonction VLOOKUP de ne rechercher que les correspondances exactes.

Voici comment fonctionne la formule VLOOKUP dans l'exemple ci-dessus.

Tout d'abord, il recherche la valeur Brad dans la colonne la plus à gauche.Il recherche la valeur dans la cellule A6 de haut en bas.

Une fois qu'il a trouvé la valeur, il se déplace vers la droite dans la deuxième colonne et saisit la valeur qu'il contient.

Vous pouvez utiliser la même construction de formule pour obtenir le score de n'importe qui dans n'importe quel sujet.

Par exemple, pour trouver le score de Maria en chimie, utilisez la formule RECHERCHEV suivante :

=RECHERCHEV("Maria",$A$3:$E$10,4,0)

Dans l'exemple ci-dessus, la valeur de recherche (nom de l'étudiant) est entrée entre guillemets doubles.Vous pouvez également utiliser des références de cellule qui contiennent des valeurs de recherche.

L'avantage d'utiliser des références de cellule est que cela rend la formule dynamique.

Par exemple, si vous avez une cellule avec le nom d'un élève et que vous obtenez des notes en mathématiques, lorsque vous modifiez le nom de l'élève, les résultats sont automatiquement mis à jour (comme indiqué ci-dessous) :

Si vous saisissez une valeur de recherche introuvable dans la colonne la plus à gauche, une erreur #N/A est renvoyée.

Exemple 2 - Recherche bidirectionnelle

Dans l'exemple 1 ci-dessus, nous avons codé en dur les valeurs des colonnes.Par conséquent, la formule renverra toujours le score de Math car nous utilisons 2 comme numéro d'index de colonne.

Mais que se passe-t-il si vous souhaitez rendre dynamiques à la fois la valeur VLOOKUP et le numéro d'index de la colonne.Par exemple, comme indiqué ci-dessous, vous pouvez modifier le nom de l'étudiant ou le nom du sujet et la formule VLOOKUP obtiendra le score correct.Voici un exemple de formule RECHERCHEV bidirectionnelle.

Voici un exemple de fonction RECHERCHEV bidirectionnelle.

Pour rendre cette formule de recherche bidirectionnelle, vous devez également rendre la colonne dynamique.Ainsi, lorsque l'utilisateur change de sujet, la formule sélectionne automatiquement la bonne colonne (2 pour les maths, 3 pour la physique, etc.).

Pour ce faire, vous devez utiliser la fonction MATCH comme paramètre de colonne.

Voici la formule RECHERCHEV qui fera cela :

=VLOOKUP(G4,$A$3:$E$10,MATCH(H3,$A$2:$E$2,0),0)

La formule ci-dessus utilise MATCH(H3,$A$2:$E$2,0) comme numéro de colonne.La fonction MATCH prend le nom du sujet comme valeur de recherche (dans H3) et renvoie sa position dans A2:E2.Donc, si vous utilisez Math, il renverra 2 car Math se trouve dans B2 (qui est la deuxième cellule de la plage de tableau spécifiée).

Exemple 3 - Utilisation de la liste déroulante comme valeur de recherche

Dans l'exemple ci-dessus, nous devons saisir les données manuellement.Cela peut prendre du temps et être source d'erreurs, surtout si vous avez beaucoup de valeurs de recherche.

Dans ce cas, une bonne idée serait de créer une liste déroulante de valeurs de recherche (dans ce cas, il pourrait s'agir du nom et du sujet de l'étudiant) et de simplement sélectionner dans la liste.

Selon la sélection, la formule mettra automatiquement à jour le résultat.

Comme indiqué ci-dessous:

Il s'agit d'un excellent composant de tableau de bord car vous pouvez avoir un énorme ensemble de données de centaines d'étudiants dans le backend, mais les utilisateurs finaux (par exemple, les enseignants) peuvent simplement descendre du fichier .

Comment puis-je faire cela:

La formule VLOOKUP utilisée dans cet exemple est la même que celle utilisée dans l'exemple 2.

=VLOOKUP(G4,$A$3:$E$10,MATCH(H3,$A$2:$E$2,0),0)

Les valeurs de recherche ont été converties en listes déroulantes.

Voici les étapes pour créer une liste déroulante :

• Sélectionnez la cellule qui a besoin d'une liste déroulante.Dans cet exemple, en G4, nous avons besoin du nom de l'élève.
• Accédez à Données -> Outils de données -> Validation des données.
• Dans l'onglet Paramètres de la boîte de dialogue Validation des données, sélectionnez Liste dans la liste déroulante Autoriser.
• Dans Source, sélectionnez $A$3 :$A$10
• Cliquez sur OK.

Vous verrez maintenant la liste déroulante dans la cellule G4.De même, vous pouvez en créer un dans H3 pour un thème.

Exemple 4 - Recherche à trois voies

Qu'est-ce qu'une recherche à trois voies ?

Dans l'exemple 2, nous avons utilisé une table de recherche contenant les scores des élèves dans différentes matières.Ceci est un exemple de recherche bidirectionnelle car nous utilisons deux variables pour obtenir les scores (nom de l'étudiant et nom du sujet).

Maintenant, disons que dans un an, un étudiant va passer trois niveaux d'examens différents, des examens unitaires, des examens de mi-session et des examens finaux (c'est l'examen de mes jours d'étudiant).

Une recherche à trois voies sera en mesure d'obtenir le score d'un étudiant pour un sujet spécifié à partir d'un niveau d'examen spécifié.

Comme indiqué ci-dessous:

Dans l'exemple ci-dessus, la fonction VLOOKUP peut rechercher et renvoyer les notes des étudiants spécifiés dans les matières spécifiées dans trois tableaux différents (tests unitaires, examens intermédiaires et finaux).

Voici la formule utilisée dans la cellule H4 :

=VLOOKUP(G4,CHOOSE(IF(H2="Unit Test",1,IF(H2="Midterm",2,3)),$A$3:$E$7,$A$11:$E$15,$A$19:$E$23),MATCH(H3,$A$2:$E$2,0),0)

Cette formule utilise la fonction CHOISIR pour s'assurer que la bonne table est référencée.Analysons la partie CHOISIR de la formule :

CHOOSE(IF(H2=”Unit Test”,1,IF(H2=”Midterm”,2,3)),$A$3:$E$7,$A$11:$E$15,$A$19:$E$23)

Le premier argument de la formule est IF(H2=”Unit Test”,1,IF(H2=”Midterm”,2,3)), qui examine la cellule H2 et voit le niveau de test référencé.S'il s'agit d'un test unitaire, $A$3:$E$7 est renvoyé, qui contient le score du test unitaire.Renvoie $A$11:$E$15 s'il s'agit d'un examen de mi-session, sinon renvoie $A$19:$E$23.

Cela rend le tableau de la table VLOOKUP dynamique, ce qui en fait une recherche à trois voies.

Exemple 5 - Obtenir la dernière valeur d'une liste

Vous pouvez créer une formule VLOOKUP pour obtenir la dernière valeur d'une liste.

Le plus grand nombre positif que vous pouvez utiliser dans Excel est 9.99999999999999E + 307 . Cela signifie également que le plus grand numéro de recherche dans le numéro VLOOKUP est le même.

Je ne pense pas que vous aurez jamais besoin de calculs impliquant des nombres aussi grands.C'est exactement ce que nous pouvons utiliser pour obtenir le dernier numéro de la liste.

Supposons que vous ayez un jeu de données comme celui-ci(en A1:A14), et vous souhaitez obtenir le dernier numéro de la liste.

Voici la formule que vous pouvez utiliser :

= RECHERCHEV(9.99999999999999E+307,$A$1:$A$14,VRAI)

Notez que la formule ci-dessus utilise une correspondance approximative VLOOKUP  (Notez le VRAI à la fin de la formule, pas FAUX ou 0).Notez également que cette formule VLOOKUP fonctionne sans trier la liste.

Voici comment fonctionne la fonction VLOOKUP approximative.Il scanne la colonne la plus à gauche de haut en bas.

• Cette valeur est renvoyée si une correspondance exacte est trouvée.
• S'il trouve une valeur supérieure à la valeur de recherche, il renvoie la valeur dans la cellule au-dessus.
• Si la valeur de recherche est supérieure à toutes les valeurs de la liste, la dernière valeur est renvoyée.

Dans l'exemple ci-dessus, le troisième cas est à l'œuvre.

en raison de9.99999999999999E + 307est le plus grand nombre pouvant être utilisé dans Excel, donc lorsqu'il est utilisé comme valeur de recherche, il renvoie le dernier nombre de la liste.

De même, vous pouvez également l'utiliser pour renvoyer le dernier élément de texte de la liste.Voici la formule qui peut le faire :

=RECHERCHEV("zzz",$A$1:$A$8,1, VRAI )

Suivez la même logique.Excel examine tous les noms, et comme zzz est considéré comme plus grand que tout nom/texte commençant par une lettre avant zzz, il renverra le dernier élément de la liste.

Exemple 6 - Recherche partielle à l'aide de caractères génériques et VLOOKUP

Les caractères génériques Excel sont utiles dans de nombreuses situations.

C'est cette potion magique qui donne à votre recette des super pouvoirs.

Une recherche partielle est requise lorsque vous devez rechercher une valeur dans une liste et qu'il n'y a pas de correspondance exacte.

Par exemple, supposons que vous disposiez d'un jeu de données comme celui-ci et que vous souhaitiez rechercher la société ABC dans une liste, mais que la liste contienne ABC Ltd au lieu de ABC.

Vous ne pouvez pas utiliser ABC comme valeur de recherche car il n'y a pas de correspondance exacte dans la colonne A.Des correspondances approximatives peuvent également entraîner des résultats incorrects et la liste doit être triée par ordre croissant.

Cependant, vous pouvez utiliser des caractères génériques dans la fonction VLOOKUP pour obtenir des correspondances.

Saisissez la formule suivante dans la cellule D2 et faites-la glisser vers d'autres cellules :

=RECHERCHEV("*"&C2&"*",$A$2:$A$8,1,FAUX)

Comment fonctionne cette formule ?

Dans la formule ci-dessus, au lieu d'utiliser la valeur de recherche telle quelle, elle est entourée d'astérisques génériques (*) - "*"&C2&"*"

Les astérisques sont des caractères génériques dans Excel qui peuvent représenter n'importe quel nombre de caractères.

Utilisez des astérisques autour de la valeur de recherche pour indiquer à Excel qu'il doit rechercher tout texte contenant le mot en C2.Il peut avoir n'importe quel nombre de caractères avant ou après le texte en C2.

Par exemple, la cellule C2 contient ABC, donc la fonction RECHERCHEV examine les noms dans A2:A8 et recherche ABC.Il trouve une correspondance dans la cellule A2 car elle contient ABC d'ABC Ltd. Peu importe s'il y a des caractères à gauche ou à droite de ABC.Il sera considéré comme une correspondance jusqu'à ce qu'il y ait ABC dans la chaîne de texte.

Remarque : La fonction RECHERCHEV renvoie toujours la première valeur correspondante et arrête les recherches ultérieures.Donc s'il y a ABC dans la liste Ltdet ABC Corporation, il renverra le premier et ignorera le reste.

Exemple 7 - VLOOKUP renvoie une erreur malgré la correspondance de la valeur de recherche

Cela vous rendra fou lorsque vous verrez qu'il existe une valeur de recherche correspondante et que la fonction VLOOKUP renvoie une erreur.

Par exemple, dans le cas ci-dessous, il y a une correspondance (Matt), mais la fonction VLOOKUP renvoie toujours une erreur.

Maintenant, bien que nous puissions voir qu'il y a correspondance, ce que nous ne pouvons pas voir à l'œil nu, c'est qu'il peut y avoir des espaces de début ou de fin.Si vous avez ces espaces supplémentaires avant, après ou entre la valeur de recherche, il ne s'agit pas d'une correspondance exacte.

Cela se produit généralement lorsque vous importez des données à partir d'une base de données ou obtenez des données de quelqu'un d'autre.Ces espaces de début/de fin ont tendance à s'infiltrer.

La solution ici est la fonction TRIM.Il supprime tous les espaces de début ou de fin ou les espaces supplémentaires entre les mots.

Voici la formule qui vous donnera le bon résultat.

=RECHERCHEV("Matt",TRIM($A$2:$A$9),1,0)

Puisqu'il s'agit d'une formule matricielle, utilisez Ctrl+Maj+Entrée au lieu d'Entrée.

Une autre approche pourrait consister à traiter d'abord votre tableau de recherche avec la fonction TRIM pour vous assurer que tous les espaces supplémentaires ont disparu, puis à utiliser la fonction VLOOKUP comme d'habitude.

Exemple 8 - Effectuer une recherche sensible à la casse

Par défaut, les valeurs de recherche dans la fonction VLOOKUP ne sont pas sensibles à la casse.Par exemple, si votre valeur de recherche est MATT, matt ou Matt, c'est la même chose pour la fonction VLOOKUP.Il renvoie la première valeur correspondante quelle que soit la casse.

Mais si vous voulez une recherche sensible à la casse, vous devez utiliser la fonction EXACT et la fonction VLOOKUP.

Ceci est un exemple:

Comme vous pouvez le voir, les trois cellules ont le même nom (en A2, A4 et A5) mais avec des majuscules différentes.À droite, nous avons trois noms (Matt, MATT et Matt) et leurs scores en mathématiques.

La fonction RECHERCHEV n'est actuellement pas équipée pour gérer les valeurs de recherche sensibles à la casse.Dans l'exemple ci-dessus, il renvoie toujours 38, qui est le score de Matt en A2.

Pour le rendre sensible à la casse, nous devons utiliser une colonne d'assistance (comme indiqué ci-dessous) :

Pour obtenir la valeur dans la colonne d'aide, utilisez la fonction =ROW().Il n'obtiendra que le numéro de ligne dans la cellule.

Une fois que vous avez la colonne d'assistance, voici la formule qui donne un résultat de recherche sensible à la casse.

=VLOOKUP(MAX(EXACT(E2,$A$2:$A$9)*(ROW($A$2:$A$9))),$B$2:$C$9,2,0)

Maintenant, décomposons-le et comprenons ce qu'il fait :

• EXACT(E2,$A$2:$A$9) – Cette partie compare la valeur de recherche dans E2 avec toutes les valeurs dans A2:A9.Il renvoie un tableau de TRUE/FALSE, où TRUE est renvoyé dans le cas d'une correspondance exacte.Dans ce cas, il renverra le tableau suivant : {TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE}.
• EXACT(E2,$A$2:$A$9)*(ROW($A$2:$A$9) - cette partie multiplie le tableau TRUE/FALSE avec le numéro de ligne. Tant qu'il y a TRUE, il donnera le numéro de ligne , sinon Il donne 0. Dans ce cas il renvoie {2;0;0;0;0;0;0;0}.
• MAX(EXACT(E2,$A$2:$A$9)*(ROW($A$2:$A$9))) – 這部分返回數字數組中的最大值。Dans ce cas, il renverra 2 (qui est le numéro de ligne exact).
• Maintenant, nous utilisons simplement ce nombre comme valeur de recherche et utilisons le tableau de recherche comme B2: C9

Remarque : puisqu'il s'agit d'une formule matricielle, utilisez Ctrl + Maj + Entrée au lieu de simplement taper.

Exemple 9 - Utilisation de VLOOKUP avec plusieurs conditions

La fonction Excel VLOOKUP, dans sa forme de base, recherche une valeur de recherche et renvoie la valeur correspondante à partir d'une ligne spécifiée.

Mais généralement VLOOKUP est nécessaire dans Excel avec plusieurs critères.

Supposons que vous ayez des données avec des noms d'élèves, des types de tests et des scores en mathématiques (indiqués ci-dessous) :

L'utilisation de la fonction VLOOKUP pour obtenir le score en mathématiques de chaque élève à son niveau de test respectif peut être un défi.

Par exemple, si vous essayez d'utiliser VLOOKUP avec Matt comme valeur de recherche, il renverra toujours 91, qui est le score de la première occurrence de Matt dans la liste.Pour obtenir le score Matt pour chaque type d'examen (unité, mi-session et final), vous devez créer une valeur de recherche unique.

Cela peut être fait en utilisant des colonnes d'assistance.La première étape consiste à insérer une colonne auxiliaire à gauche de la fraction.

Maintenant, pour créer un qualificatif unique pour chaque instance d'un nom, utilisez la formule suivante en C2 : =A2&"|"&B2

Copiez cette formule dans toutes les cellules de la colonne d'assistance.Cela créera une valeur de recherche unique pour chaque instance du nom (comme indiqué ci-dessous) :

Maintenant, bien qu'il y ait des noms en double, lorsque les noms sont combinés avec des niveaux d'examen, il n'y a pas de doublons.

C'est facile car vous pouvez maintenant utiliser la valeur de la colonne d'assistance comme valeur de recherche.

C'est la formule qui vous donne le résultat en G3:I8.

=RECHERCHEV($F3&"|"&G$2,$C$2:$D$19,2,0)

Ici, nous combinons le nom de l'étudiant et le niveau d'examen pour obtenir la valeur de recherche, nous utilisons cette valeur de recherche pour vérifier dans la colonne d'assistance les enregistrements correspondants.

Remarque : Dans l'exemple ci-dessus, nous avons utilisé | Utilisé comme délimiteur lors de l'ajout de texte aux colonnes auxiliaires.Dans certains cas très rares (mais possibles), vous pouvez avoir deux critères différents, mais les combiner finira par donner le même résultat.Ceci est un exemple:

Notez que même si A2 et A3 sont différents et que B2 et B3 sont différents, la combinaison est finalement la même.Cependant, si vous utilisez des délimiteurs, même la combinaison sera différente (D2 et D3).

Voici un tutoriel sur la façon d'utiliser VLOOKUP avec plusieurs conditions sans utiliser de colonnes d'assistance.

Exemple 10 - Gestion des erreurs lors de l'utilisation de la fonction VLOOKUP

La fonction RECHERCHEV d'Excel renvoie une erreur lorsque la valeur de recherche spécifiée est introuvable.Si VLOOKUP ne trouve pas de valeur, vous ne voulez probablement pas que des valeurs d'erreur laides interfèrent avec l'esthétique de vos données.

Vous pouvez facilement supprimer les valeurs d'erreur avec le texte intégral de n'importe quelle signification, comme "Non disponible" ou "Non trouvé".

Par exemple, dans l'exemple ci-dessous, lorsque vous essayez de trouver le score de Brad dans la liste, une erreur est renvoyée car le nom de Brad ne figure pas dans la liste.

Pour supprimer cette erreur et la remplacer par quelque chose de significatif, encapsulez la fonction RECHERCHEV dans une fonction SIERREUR.

Voici la formule :

=SIERREUR(RECHERCHEV(D2,$A$2:$B$7,2,0),"Non trouvé")

La fonction SIERREUR vérifie si la valeur renvoyée par le premier argument (dans ce cas, la fonction RECHERCHEV) est une erreur.S'il ne s'agit pas d'une erreur, renvoyez la valeur via la fonction VLOOKUP, sinon renvoyez Not Found.

La fonction SIERREUR est disponible depuis Excel 2007.Si vous utilisez une version précédente, veuillez utiliser les fonctions suivantes :

=IF(ISERROR(VLOOKUP(D2,$A$2:$B$7,2,0)),"Not Found",VLOOKUP(D2,$A$2:$B$7,2,0))

C'est tout pour ce tutoriel VLOOKUP.

J'essaie de présenter l'exemple principal d'utilisation de la fonction Vlookup dans Excel.Faites-moi savoir dans la section des commentaires si vous souhaitez voir plus d'exemples ajoutés à cette liste.

Fonctions Excel associées :

• Fonction RECHERCHEH d'Excel.
• Fonction Excel XLOOKUP
• Fonction d'index Excel.
• Fonction indirecte Excel.
• Fonction de correspondance Excel.
• Fonction de décalage Excel.